chore(packaging: arch): prepare PKGBUILD for GUI and Oomox theme plug…

…in (re: #129)

Makefile

@@ -34,6 +34,7 @@ install_gui: install_import_random
 
 	install -d $(DEST_PREFIX)/bin/
 	install -Dp -m 755 "$(PACKAGING_TMP_DIR)/packaging/bin/oomox-gui" "$(DEST_PREFIX)/bin/"
+	install -Dp -m 755 "$(PACKAGING_TMP_DIR)/packaging/bin/themix-gui" "$(DEST_PREFIX)/bin/"
 
 	install -d $(DEST_PREFIX)/share/applications/
 	install -Dp -m 644 "$(PACKAGING_TMP_DIR)/packaging/com.github.themix_project.Oomox.desktop" "$(DEST_PREFIX)/share/applications/"

packaging/arch/PKGBUILD_gui

@@ -0,0 +1,47 @@
+# Maintainer: Yauhen Kirylau <actionless DOT loveless PLUS aur AT gmail MF com>
+# Upstream URL: https://github.com/themix-project/oomox
+
+pkgname=themix-gui-git
+pkgver=1.12.6
+pkgrel=1
+pkgdesc="Plugin-based theme designer GUI for
+ environments (like GTK2, GTK3, Cinnamon, GNOME, MATE, Openbox, Xfwm),
+ icons, and terminal palettes."
+arch=('x86_64' 'i686')
+url="https://github.com/themix-project/oomox"
+license=('GPL3')
+source=(
+	"git+https://github.com/themix-project/oomox.git#branch=master"
+)
+md5sums=(
+	"SKIP"
+)
+depends=(
+	'gtk3'
+	'python-gobject'
+)
+makedepends=(
+	'git'
+)
+optdepends=(
+	'xorg-xrdb: for the `xresources` theme'
+	'themix-theme-oomox: Theme Style plugin'
+)
+provides=('themix-gui')
+conflicts=('themix-gui')
+
+pkgver() {
+	cd "${srcdir}/oomox"
+	git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+package() {
+	_oomox_dir=/opt/oomox
+	_oomox_gui_dir=${_oomox_dir}/oomox_gui
+
+	cd "${srcdir}/oomox"
+	make DESTDIR="${pkgdir}" APPDIR="${_oomox_dir}" PREFIX="/usr" install_gui
+	python -O -m compileall ${pkgdir}${_oomox_gui_dir} -d ${_oomox_gui_dir}
+}
+
+# vim: ft=PKGBUILD

packaging/arch/PKGBUILD_theme_oomox

@@ -0,0 +1,62 @@
+# Maintainer: Yauhen Kirylau <actionless DOT loveless PLUS aur AT gmail MF com>
+# Upstream URL: https://github.com/themix-project/oomox-gtk-theme
+
+pkgname=themix-theme-oomox-git
+pkgver=1.11.1
+pkgrel=1
+pkgdesc="Oomox theme plugin
+ (GTK2, GTK3, Cinnamon, Metacity, Openbox, Qt5ct, Unity, Xfwm) for Themix GUI designer.
+ Have a hack for HiDPI in GTK2."
+arch=('x86_64' 'i686')
+url="https://github.com/themix-project/oomox-gtk-theme"
+license=('GPL3')
+source=(
+	"git+https://github.com/themix-project/oomox.git#branch=master"
+	"git+https://github.com/themix-project/oomox-gtk-theme.git#branch=master"
+)
+md5sums=(
+	"SKIP"
+	"SKIP"
+)
+depends=(
+	'gtk3'
+	'glib2'  # oomox, materia, arc
+	'gdk-pixbuf2'  # oomox, materia, arc
+	'gtk-engine-murrine'  # oomox, materia, arc
+	'gtk-engines'  # oomox, materia, arc
+	'sassc'  # oomox, materia, arc
+	'librsvg'  # oomox, gnome-colors
+	'sed'  # oomox, materia, arc, gnome-colors, archdroid
+	'findutils'  # oomox, materia, arc, gnome-colors, arch-droid
+	'grep'  # oomoxify, oomox, materia, arc, gnome-colors
+	'bc'  # oomoxify, oomox, materia, arc, gnome-colors
+)
+makedepends=(
+	'git'
+)
+optdepends=(
+	'themix-gui: GUI'
+)
+options=(
+	'!strip'
+)
+provides=('themix-theme-oomox')
+conflicts=('themix-theme-oomox')
+
+pkgver() {
+	cd "${srcdir}/oomox-gtk-theme"
+	git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+package() {
+	_oomox_dir=/opt/oomox
+	_oomox_gui_dir=${_oomox_dir}/oomox_gui
+	cd "${srcdir}/oomox"
+
+	rm -fr plugins/theme_oomox/gtk-theme
+	mv "${srcdir}/oomox-gtk-theme" plugins/theme_oomox/gtk-theme
+	make DESTDIR="${pkgdir}" APPDIR="${_oomox_dir}" PREFIX="/usr" install_theme_oomox
+	python -O -m compileall ${pkgdir}${_oomox_gui_dir} -d ${_oomox_gui_dir}
+}
+
+# vim: ft=PKGBUILD

packaging/bin/themix-gui

@@ -0,0 +1,3 @@
+#!/bin/sh
+cd /opt/oomox/ &&
+exec python3 -m oomox_gui "$@"