some minor enhancements

.gitignore

@@ -0,0 +1 @@
+.vagrant

Makefile

@@ -0,0 +1,12 @@
+apply = puppet apply --noop --modulepath=tests/modules
+
+smoke:
+	$(apply) tests/smoke.pp
+	$(apply) tests/client.pp
+	$(apply) tests/autodetect.pp
+
+test: tests/*.pp
+	find tests -name \*.pp | xargs -n 1 -t $(apply)
+
+vm:
+	vagrant up

README.md

@@ -0,0 +1,169 @@
+# puppet-apt_cacher_ng
+
+A Puppet module for [apt-cacher-ng], with a `Vagrantfile` for quick
+deployment on [Vagrant].
+
+Requires puppetlabs [stdlib] module
+
+Original author: [Alban Peignier]
+
+Other contributors:
+
+* [Garth Kidd]: Vagrantfile and smoke tests
+* [Gabriel Filion]: version specification, file layout flexibility
+* [Lekensteyn]: auto-detect/fallback script (see [askubuntu:54099])
+
+## Usage
+
+The apt\_cacher\_ng module provides two main "entry points": one for the server
+and one for clients.
+
+### Server
+
+The main class, `apt_cacher_ng` will install the apt_cacher_ng server. You can
+simply include the class, or if you want to install a specific version you can
+use the `version` parameter like the following:
+
+```puppet
+class { 'apt_cacher_ng':
+  version => '0.4.6-1ubuntu1',
+}
+```
+
+* The server will be available on the default port (3142).
+* The server will not use itself as a cache by default.
+
+If you'd like to set an admin password for the web interface, you can do so
+with the `admin_user` and `admin_pw` parameters. Make sure to set both
+parameters (or none). Also, keep in mind that only alphanumeric characters,
+dashes and underscores are accepted for the password:
+
+```puppet
+class { 'apt_cacher_ng':
+  admin_user => 'clown_goose',
+  admin_pw   => '12tgDd23456ytGfDW32',
+}
+```
+
+### Client
+
+The class `apt_cacher_ng::client` helps you configure a server as a client
+for an apt proxy. It has two "modes" of configuration: setting up one proxy
+with no alternative, and setting up a list of proxies where the first in the
+list that is currently available will be used (autodetection).
+
+Both modes use the `servers` parameter to the `apt_cacher_ng::client` class.
+This parameter should be an array that contains server strings. The servers
+strings are fqdn (or IP address) and port in the same mannger as you'd write
+it for HTTP, without the "http://" prefix.
+
+* To setup one proxy with no fallback, set the `autodetect` parameter to
+  `false` and make sure to provide only one server value for the `servers`
+  parameter:
+
+    ```puppet
+    class { 'apt_cacher_ng::client':
+      servers    => ['192.168.31.42:3142'],
+      autodetect => false,
+    }
+    ```
+
+  Per [askubuntu:54099], you'll need to do this on older Ubuntu and Debian
+  releases. Lucid and Squeeze support `Acquire::http::ProxyAutoDetect`;
+  Karmic and Lenny don't.
+
+* To setup a list of proxies, keep the `autodetect` paramter to a value of
+  `true` (this is the default value) and specify all servers in the `servers`
+  parameter:
+
+    ```puppet
+    class { 'apt_cacher_ng::client':
+      servers => ['192.168.30.42:3142', '192.168.31.42:3142'],
+    }
+    ```
+
+  When setting up autodetect, you can override the number of seconds till
+  timeout (default is 30):
+
+    ```puppet
+    class { 'apt_cacher_ng::client':
+      servers => ['192.168.30.42:3142', '192.168.31.42:3142'],
+      timeout => 15,
+    }
+    ```
+
+  Also when setting up autodetect, you can set the `verbose` parameter to
+  `false` to make the autodetection process act quietly:
+
+    ```puppet
+    class { 'apt_cacher_ng::client':
+      servers => ['192.168.30.42:3142', '192.168.31.42:3142'],
+      verbose => false,
+    }
+    ```
+
+## Providing an apt cache for your Vagrant virtual machines
+
+To install apt-cacher-ng on a fresh box in [Vagrant]:
+
+    vagrant up aptcache
+
+The `Vagrantfile` specifies a box named `aptcache` providing its service
+from `http://192.168.31.42:3142`. You should be able to browse to it from
+your host OS to manage it.
+
+### Using the apt cache
+
+To configure your own Vagrant box to access the `aptcache` box:
+
+* Configure your VM for [host-only networking], by adding the following line
+  to your `Vagrantfile`:
+
+        config.vm.network :hostonly, "192.168.31.2"
+
+    (Change the final octet (`2`) to make sure it's unique on your machine. 
+    Don't use `1`: it'll probably be used by your host OS for its `vboxnet0`
+    adapter.)
+
+* Inside your box, create `/etc/apt/apt.conf.d/71proxy` with the line:
+
+        Acquire::http { Proxy "http://192.168.31.42:3142"; };
+
+    If you're using [Puppet Provisioning], put this in your `manifest_file`, 
+    e.g. `my_manifest.pp`:
+
+        file { "/etc/apt/apt.conf.d/71proxy": 
+          owner   => root,
+          group   => root,
+          mode    => '0644',
+          content => 'Acquire::http { Proxy "http://192.168.31.42:3142"; };',
+        }
+
+    You could also install the Puppet module and use `apt_cacher_ng::client`
+    as above.
+
+## Testing
+
+To perform a [smoke test]: 
+
+    make smoke
+
+To smoke test both the module and the `Vagrantfile`'s `manifest_file`:
+
+    make test
+
+To test the module properly, install [Vagrant] and:
+
+    make vm
+
+[apt-cacher-ng]: http://www.unix-ag.uni-kl.de/~bloch/acng/
+[smoke test]: http://docs.puppetlabs.com/guides/tests_smoke.htm
+[stdlib]: https://github.com/puppetlabs/puppetlabs-stdlib
+[Alban Peignier]: https://github.com/albanpeignier
+[Garth Kidd]: https://github.com/garthk
+[Gabriel Filion]: https://github.com/lelutin
+[Lekensteyn]: http://www.lekensteyn.nl/
+[Vagrant]: http://vagrantup.com/
+[host-only networking]: http://vagrantup.com/docs/host_only_networking.html
+[askubuntu:54099]: http://askubuntu.com/a/54099
+[Puppet Provisioning]: http://vagrantup.com/docs/provisioners/puppet.html

Vagrantfile

@@ -0,0 +1,19 @@
+# -*- mode: ruby -*-
+# vi: set ft=ruby :
+
+Vagrant::Config.run do |config|
+  config.vm.define :aptcache do |aptcache|
+    aptcache.vm.box = "lucid32"
+    aptcache.vm.host_name = "aptcache"
+    aptcache.vm.share_folder "module", "/tmp/vagrant-puppet/modules/apt_cacher_ng", ".", :create => true
+    aptcache.vm.network :hostonly, "192.168.31.42"
+    aptcache.vm.forward_port 3142, 3142
+    aptcache.vm.forward_port 22, 2242
+    aptcache.ssh.max_tries = 150
+    aptcache.vm.provision :puppet do |puppet|
+      puppet.manifests_path = "tests"
+      puppet.manifest_file = "vagrant.pp"
+      puppet.options = ["--modulepath", "/tmp/vagrant-puppet/modules"]
+    end
+  end
+end

files/30detectproxy

@@ -0,0 +1,8 @@
+# Fail immediately if a file could not be retrieved. Comment if you have a bad
+# Internet connection
+Acquire::Retries 0;
+
+# undocumented feature which was found in the source. It should be an absolute
+# path to the program, no arguments are allowed. stdout contains the proxy
+# server, stderr is shown (in stderr) but ignored by APT
+Acquire::http::ProxyAutoDetect "/etc/apt/detect-http-proxy";

files/acng.conf

@@ -79,3 +79,6 @@ ExTreshold: 4
 #VfilePattern = (^|.*?/)(Index|Packages\.gz|Packages\.bz2|Release|Release\.gpg|Sources\.gz|Sources\.bz2|release|index\.db-.*\.gz|Contents-[^/]*\.gz|pkglist[^/]*\.bz2|rclist[^/]*\.bz2|Translation[^/]*\.bz2)$
 #PfilePattern = .*(\.deb|\.rpm|\.dsc|\.tar\.gz\.gpg|\.tar\.gz|\.diff\.gz|\.diff\.bz2|\.jigdo|\.template|changelog|copyright|\.udeb|\.diff/.*\.gz|vmlinuz|initrd\.gz)$
 
+# workaround to allow use of http.debian.net, see bug #683803
+# http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=683803
+RedirMax: 0

manifests/client.pp

@@ -0,0 +1,25 @@
+class apt_cacher_ng::client (
+  $servers = $apt_cacher_ng::client::params::servers,
+  $autodetect = $apt_cacher_ng::client::params::autodetect,
+  $verbose = $apt_cacher_ng::client::params::verbose,
+  $timeout = $apt_cacher_ng::client::params::timeout
+) inherits apt_cacher_ng::client::params {
+
+  validate_array($servers)
+  if empty($servers) {
+    fail('$servers must contain at least one value.')
+  }
+  if (! $autodetect) and (count($servers) > 1) {
+    fail('With $autodetect turned off, you can only specify one server.')
+  }
+  validate_bool($autodetect)
+  validate_bool($verbose)
+  if !is_integer($timeout) {
+    fail('Parameter $timeout is expected to be an integer value.')
+  }
+
+  anchor { 'apt_cacher_ng::client::begin': } ->
+  class { 'apt_cacher_ng::client::config': } ->
+  anchor { 'apt_cacher_ng::client::end': }
+
+}

manifests/client/autodetect.pp

@@ -0,0 +1,32 @@
+class apt_cacher_ng::client::autodetect (
+  $ensure = present
+) {
+
+  file { '/etc/apt/apt.conf.d/30detectproxy':
+    ensure => $ensure,
+    source => 'puppet:///modules/apt_cacher_ng/30detectproxy',
+    owner  => 'root',
+    group  => 0,
+    mode   => '0644',
+  }
+
+  $show_proxy_messages = bool2num($apt_cacher_ng::client::verbose)
+
+  $proxies = $apt_cacher_ng::client::servers
+
+  file { '/etc/apt/detect-http-proxy':
+    ensure  => $ensure,
+    content => template('apt_cacher_ng/detect-http-proxy.erb'),
+    owner   => 'root',
+    group   => 0,
+    mode    => '0755',
+  }
+  file { '/etc/apt/proxy.conf':
+    ensure  => $ensure,
+    content => template('apt_cacher_ng/apt-proxy-conf.erb'),
+    owner   => 'root',
+    group   => 0,
+    mode    => '0644',
+  }
+
+}

manifests/client/config.pp

@@ -0,0 +1,16 @@
+class apt_cacher_ng::client::config {
+
+  if ! $apt_cacher_ng::client::autodetect {
+    include apt_cacher_ng::client::one_proxy
+    class { 'apt_cacher_ng::client::autodetect':
+      ensure => absent,
+    }
+  }
+  else {
+    class { 'apt_cacher_ng::client::one_proxy':
+      ensure => absent,
+    }
+    include apt_cacher_ng::client::autodetect
+  }
+
+}

manifests/client/one_proxy.pp

@@ -0,0 +1,14 @@
+class apt_cacher_ng::client::one_proxy (
+  $ensure = present
+) {
+
+  $server = $apt_cacher_ng::client::servers[0]
+  file { '/etc/apt/apt.conf.d/71proxy':
+    ensure  => $ensure,
+    content => "Acquire::http { Proxy \"http://${server}\"; };",
+    owner   => 'root',
+    group   => 0,
+    mode    => '0644',
+  }
+
+}

manifests/client/params.pp

@@ -0,0 +1,8 @@
+class apt_cacher_ng::client::params {
+
+  $servers = ['127.0.0.1:3142']
+  $autodetect = true
+  $verbose = true
+  $timeout = 30
+
+}

manifests/config.pp

@@ -0,0 +1,26 @@
+class apt_cacher_ng::config {
+
+  file { '/etc/apt-cacher-ng/acng.conf':
+    source => [
+      "puppet:///modules/site_apt_cacher_ng/${::fqdn}/acng.conf",
+      'puppet:///modules/site_apt_cacher_ng/acng.conf',
+      'puppet:///modules/apt_cacher_ng/acng.conf'
+    ],
+  }
+
+  file { '/var/cache/apt-cacher-ng':
+    ensure  => directory,
+    owner   => 'apt-cacher-ng',
+  }
+
+  $admin_user = $apt_cacher_ng::admin_user
+  $admin_pw = $apt_cacher_ng::admin_pw
+  file { '/etc/apt-cacher-ng/security.conf':
+    ensure  => present,
+    owner   => 'root',
+    group   => 'apt-cacher-ng',
+    mode    => '0640',
+    content => template('apt_cacher_ng/security.conf.erb'),
+  }
+
+}

manifests/init.pp

@@ -1,22 +1,24 @@
-class apt-cacher-ng {
+class apt_cacher_ng (
+  $version    = 'installed',
+  $admin_user = false,
+  $admin_pw   = false
+) {
 
-  package { apt-cacher-ng: }
-
-  service { apt-cacher-ng: 
-    ensure => running,
-    require => Package[apt-cacher-ng]
+  if $admin_user != false and $admin_pw != false {
+    validate_string($admin_user)
+    validate_string($admin_pw)
   }
-
-  file { "/etc/apt-cacher-ng/acng.conf":
-    source => "puppet:///apt-cacher-ng/acng.conf",
-    notify => Service[apt-cacher-ng],
-    require => Package[apt-cacher-ng]
+  else {
+    if ($admin_user != false and $admin_pw == false) or
+       ($admin_user == false and $admin_pw != false) {
+      fail('Please set either none or both of $admin_user and $admin_pw.')
+    }
   }
 
-  file { "/var/cache/apt-cacher-ng":
-    owner => apt-cacher-ng,
-    ensure => directory,
-    require => Package[apt-cacher-ng]
-  }
+  anchor { 'apt_cacher_ng::begin': }
+  -> class { 'apt_cacher_ng::install': }
+  -> class { 'apt_cacher_ng::config': }
+  ~> class { 'apt_cacher_ng::service': }
+  -> anchor { 'apt_cacher_ng::end': }
 
 }

manifests/install.pp

@@ -0,0 +1,7 @@
+class apt_cacher_ng::install {
+
+  package { 'apt-cacher-ng':
+    ensure => $apt_cacher_ng::version,
+  }
+
+}