Thread and Address Sanitizer CI

.github/workflows/ci.yaml

@@ -0,0 +1,30 @@
+# This config uses industrial_ci (https://github.com/ros-industrial/industrial_ci.git).
+# For troubleshooting, see readme (https://github.com/ros-industrial/industrial_ci/blob/master/README.rst)
+
+name: CI
+
+on:
+  workflow_dispatch:
+  pull_request:
+  push:
+    branches:
+      - ros2
+
+jobs:
+  ci:
+    strategy:
+      fail-fast: false
+      matrix:
+        env:
+          - TARGET_CMAKE_ARGS: -DENABLE_SANITIZER_ADDRESS=ON -DCMAKE_BUILD_TYPE=Debug
+            NAME: Address Sanitizer
+          - TARGET_CMAKE_ARGS: -DENABLE_SANITIZER_THREAD=ON -DCMAKE_BUILD_TYPE=Debug
+            NAME: Thread Sanitizer
+    env:
+      ROS_DISTRO: rolling
+    runs-on: ubuntu-latest
+    name: ${{ matrix.env.NAME }}
+    steps:
+      - uses: actions/checkout@v2
+      - uses: 'ros-industrial/industrial_ci@master'
+        env: ${{matrix.env}}

cmake/sanitizers.cmake

@@ -0,0 +1,68 @@
+function(enable_sanitizers project_name)
+
+  if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" OR CMAKE_CXX_COMPILER_ID MATCHES ".*Clang")
+    option(ENABLE_COVERAGE "Enable coverage reporting for gcc/clang" OFF)
+
+    if(ENABLE_COVERAGE)
+      target_compile_options(${project_name} INTERFACE --coverage -O0 -g -fno-omit-frame-pointer)
+      target_link_libraries(${project_name} INTERFACE --coverage)
+    endif()
+
+    set(SANITIZERS "")
+
+    option(ENABLE_SANITIZER_ADDRESS "Enable address sanitizer" OFF)
+    if(ENABLE_SANITIZER_ADDRESS)
+      list(APPEND SANITIZERS "address")
+    endif()
+
+    option(ENABLE_SANITIZER_LEAK "Enable leak sanitizer" OFF)
+    if(ENABLE_SANITIZER_LEAK)
+      list(APPEND SANITIZERS "leak")
+    endif()
+
+    option(ENABLE_SANITIZER_UNDEFINED_BEHAVIOR "Enable undefined behavior sanitizer" OFF)
+    if(ENABLE_SANITIZER_UNDEFINED_BEHAVIOR)
+      list(APPEND SANITIZERS "undefined")
+    endif()
+
+    option(ENABLE_SANITIZER_THREAD "Enable thread sanitizer" OFF)
+    if(ENABLE_SANITIZER_THREAD)
+      if("address" IN_LIST SANITIZERS OR "leak" IN_LIST SANITIZERS)
+        message(WARNING "Thread sanitizer does not work with Address and Leak sanitizer enabled")
+      else()
+        list(APPEND SANITIZERS "thread")
+      endif()
+    endif()
+
+    option(ENABLE_SANITIZER_MEMORY "Enable memory sanitizer" OFF)
+    if(ENABLE_SANITIZER_MEMORY AND CMAKE_CXX_COMPILER_ID MATCHES ".*Clang")
+      message(WARNING "Memory sanitizer requires all the code (including libc++) \
+        to be MSan-instrumented otherwise it reports false positives")
+      if("address" IN_LIST SANITIZERS
+          OR "thread" IN_LIST SANITIZERS
+          OR "leak" IN_LIST SANITIZERS)
+        message(WARNING "Memory sanitizer does not work with Address, Thread and Leak sanitizer enabled")
+      else()
+        list(APPEND SANITIZERS "memory")
+      endif()
+    endif()
+
+    list(
+      JOIN
+      SANITIZERS
+      ","
+      LIST_OF_SANITIZERS)
+
+  endif()
+
+  if(LIST_OF_SANITIZERS)
+    if(NOT
+        "${LIST_OF_SANITIZERS}"
+        STREQUAL
+        "")
+      target_compile_options(${project_name} INTERFACE -fsanitize=${LIST_OF_SANITIZERS})
+      target_link_options(${project_name} INTERFACE -fsanitize=${LIST_OF_SANITIZERS})
+    endif()
+  endif()
+
+endfunction()

test/CMakeLists.txt

@@ -2,6 +2,11 @@ find_package(ament_cmake_gtest REQUIRED)
 
 include("../cmake/class_loader_hide_library_symbols.cmake")
 
+# Link this 'library' to set the compile-time options requested
+add_library(project_options INTERFACE)
+include(../cmake/sanitizers.cmake)
+enable_sanitizers(project_options)
+
 add_library(${PROJECT_NAME}_TestPlugins1 EXCLUDE_FROM_ALL SHARED plugins1.cpp)
 target_link_libraries(${PROJECT_NAME}_TestPlugins1 ${PROJECT_NAME})
 class_loader_hide_library_symbols(${PROJECT_NAME}_TestPlugins1)
@@ -27,7 +32,18 @@ ament_add_gtest(${PROJECT_NAME}_utest utest.cpp
 )
 
 if(TARGET ${PROJECT_NAME}_utest)
-  target_link_libraries(${PROJECT_NAME}_utest ${PROJECT_NAME})
+  if(ament_cmake_FOUND)
+    target_include_directories(${PROJECT_NAME}_utest
+      PUBLIC "../include")
+    target_link_libraries(${PROJECT_NAME}_utest
+      console_bridge::console_bridge)
+  else()
+    target_include_directories(${PROJECT_NAME}_utest
+      PUBLIC "../include" ${console_bridge_INCLUDE_DIRS})
+    target_link_libraries(${PROJECT_NAME}_utest)
+  endif()
+  target_link_libraries(${PROJECT_NAME}_utest ${PROJECT_NAME} project_options)
+
   if(NOT WIN32)
     target_link_libraries(${PROJECT_NAME}_utest pthread)
   endif()
@@ -41,7 +57,16 @@ ament_add_gtest(${PROJECT_NAME}_unique_ptr_test unique_ptr_test.cpp
   APPEND_LIBRARY_DIRS "${append_library_dirs}"
 )
 if(TARGET ${PROJECT_NAME}_unique_ptr_test)
-  target_link_libraries(${PROJECT_NAME}_unique_ptr_test ${PROJECT_NAME})
+  if(ament_cmake_FOUND)
+    target_include_directories(${PROJECT_NAME}_unique_ptr_test
+      PUBLIC "../include")
+  else()
+    target_include_directories(${PROJECT_NAME}_unique_ptr_test
+      PUBLIC "../include")
+    target_link_libraries(${PROJECT_NAME}_unique_ptr_test)
+  endif()
+  target_link_libraries(${PROJECT_NAME}_unique_ptr_test ${PROJECT_NAME} project_options)
+
   if(NOT WIN32)
     target_link_libraries(${PROJECT_NAME}_unique_ptr_test pthread)
   endif()